Use Variables in FOR Loop tokens?

[tinfanide]

Code: Select all

setlocal enableextensions enabledelayedexpansion

FOR /L %%A IN (1,2,7) DO (
   SET "num=%%A"
   FOR /F "tokens=!num!" %%G IN ("Mon Tue Wed Thur Fri Sat Sun") DO ECHO %%G
)

endlocal

PAUSE

I want

Mon
Wed
Fri
Sun

!num!" was unexpected at this time.
!num!" was unexpected at this time.
!num!" was unexpected at this time.
!num!" was unexpected at this time.
Press any key to continue . . .

[foxidrive]

Delayed expansion doesn't work but this is a workaround.

Code: Select all

@echo off

FOR /L %%A IN (1,2,7) DO set num=%%A&call :next
goto :skip

:next
   FOR /F "tokens=%num%" %%G IN ("Mon Tue Wed Thur Fri Sat Sun") DO ECHO %%G
goto :EOF

:skip
pause

[abc0502]

when using this:

Code: Select all

@echo off
setlocal enableextensions enabledelayedexpansion

FOR /L %%A IN (1,2,7) DO ( 
FOR /F "tokens=1" %%G IN ("Mon Tue Wed Thur Fri Sat Sun") DO ECHO %%G
)

endlocal

PAUSE

just removed the set command

It give me:

Code: Select all

Mon
Mon
Mon
Mon

[foxidrive]

You didn't use %%A in tokens. It didn't work here either.

[tinfanide]

Yes, it works.
In this case, cannot use EnableDelayedExpansion.
The CALL command seems to get to the next label and call it back to the FOR loop instead of, like, using GOTO which will never bring it back to the FOR loop.

[dbenham]

Regarding the foxidrive solution: It can be made more flexible by passing the value as a parameter instead of defining and using a fixed variable. I don't like to create unnecessary variables.

Code: Select all

@echo off
FOR /L %%A IN (1,2,7) DO call :showDay %%A
exit /b

:showDay  DayOfWeekNum
FOR /F "tokens=%1" %%G IN ("Mon Tue Wed Thur Fri Sat Sun") DO ECHO %%G
exit /b

Dave Benham