Aacini's Colors Tree

          FFFFFF
FFFF00 FFFF33 FFFF66 FFFF99 FFFFCC CCFFCC CCFFFF 99FFFF 66FFFF 33FFFF 00FFFF
FFCC00 FFCC33 FFCC66 FFCC99 FFCCCC FFCCFF CCCCFF 99CCFF 66CCFF 33CCFF 00CCFF
FF9900 FF9933 FF9966 FF9999 FF99CC FF99FF CC99FF 9999FF 6699FF 3399FF 0099FF
FF6600 FF6633 FF6666 FF6699 FF66CC FF66FF CC66FF 9966FF 6666FF 3366FF 0066FF
FF3300 FF3333 FF3366 FF3399 FF33CC FF33FF CC33FF 9933FF 6633FF 3333FF 0033FF
FF0000 FF0033 FF0066 FF0099 FF00CC FF00FF CC00FF 9900FF 6600FF 3300FF 0000FF
          CCCCCC
 
  CCFF00 CCFF33 CCFF66 CCFF99 99FF99 99FFCC 66FFCC 33FFCC 00FFCC
  CCCC00 CCCC33 CCCC66 CCCC99 99CC99 99CCCC 66CCCC 33CCCC 00CCCC
  CC9900 CC9933 CC9966 CC9999 CC99CC 9999CC 6699CC 3399CC 0099CC
  CC6600 CC6633 CC6666 CC6699 CC66CC 9966CC 6666CC 3366CC 0066CC
  CC3300 CC3333 CC3366 CC3399 CC33CC 9933CC 6633CC 3333CC 0033CC
  CC0000 CC0033 CC0066 CC0099 CC00CC 9900CC 6600CC 3300CC 0000CC
          999999
 
 
    99FF00 99FF33 99FF66 66FF66 66FF99 33FF99 00FF99
    99CC00 99CC33 99CC66 66CC66 66CC99 33CC99 00CC99
    999900 999933 999966 669966 669999 339999 009999
    996600 996633 996666 996699 666699 336699 006699
    993300 993333 993366 993399 663399 333399 003399
    990000 990033 990066 990099 660099 330099 000099
          666666
 
 
 
      66FF00 66FF33 33FF33 33FF66 00FF66
      66CC00 66CC33 33CC33 33CC66 00CC66
      669900 669933 339933 339966 009966
      666600 666633 336633 336666 006666
      663300 663333 663366 333366 003366
      660000 660033 660066 330066 000066
          333333
 
 
 
 
        33FF00 00FF00 00FF33
        33CC00 00CC00 00CC33
        339900 009900 009933
        336600 006600 006633
        333300 003300 003333
        330000 330033 000033
          000000
 
 
 
 
 

Original design by Antonio Pérez Ayala

Aacini's Colors Tree.bat 

@echo off
setlocal EnableDelayedExpansion

rem "Aacini's Colors Tree.bat": Create a safe color palette in the form of a Tree
rem Original design by Antonio Perez Ayala

rem Define the digits
set base=-1
for %%a in (00 33 66 99 CC FF) do (
   set /A base+=1
   set digit[!base!]=%%a
)
set /A baseM1=base-1

rem Define the trunk
for /L %%b in (%base%,-1,0) do (
   set a=%base%
   for /L %%a in (%base%,-1,0) do (
      if %%a neq %%b (
         set trunk[!a!][%%b]=!digit[%%a]!!digit[%%b]!!digit[%%a]!
         set /A a-=1
      )
   )
)

rem Generate the tree
(
echo =
echo [table align="center" cellpadding="3"]
set trunkHeight=1
for /L %%a in (%base%,-1,1) do set /A A=%%a-1 & for /F %%A in ("!A!") do (

   rem Trunk with no branches
   set "line="
   for /L %%i in (1,1,%base%) do set "line=!line![rowspan="!trunkHeight!"][nbsp]|"
   set value=!digit[%%a]!!digit[%%a]!!digit[%%a]!
   echo !line![rowspan="!trunkHeight!" bgcolor="#!value!"]!value!
   for /L %%i in (2,1,!trunkHeight!) do echo [nbsp]
   set /A trunkHeight+=1

   rem Bunch of branches
   for /L %%b in (%base%,-1,0) do (
      set "line="
      rem Left margin
      for /L %%i in (%%a,1,%baseM1%) do set "line=!line![nbsp]|"
      rem Left branch
      for /L %%c in (0,1,%%A) do (
         set value=!digit[%%a]!!digit[%%b]!!digit[%%c]!
         set "line=!line![bgcolor="#!value!"]!value!|"
      )
      rem Trunk with branches
      set value=!trunk[%%a][%%b]!
      set line=!line![bgcolor="#!value!"]!value!
      rem Right branch
      for /L %%c in (%%A,-1,0) do (
         set value=!digit[%%c]!!digit[%%b]!!digit[%%a]!
         set "line=!line!|[bgcolor="#!value!"]!value!"
      )
      echo !line!
   )

)

rem Bottom trunk
set "line="
for /L %%i in (1,1,%base%) do set "line=!line![rowspan="!trunkHeight!"][nbsp]|"
set value=!digit[0]!!digit[0]!!digit[0]!
echo !line![rowspan="!trunkHeight!" bgcolor="#!value!"][color="white"]!value![/color]
for /L %%i in (2,1,!trunkHeight!) do echo [nbsp]
echo [/table]

echo [color="#999999" size="-1"]Original design by Antonio Pérez Ayala[/color]
echo [hr]
echo [code:"Aacini's Colors Tree.bat" height:26em;]Aacini's Colors Tree.bat
set /P "=[" < NUL
echo /code]
) > "Aacini's Colors Tree.txt"

TextToHtml "Aacini's Colors Tree.txt" /N