New technic: set /p can read multiple lines from a file

[aGerman]

To be honest I would rather append the data at the end of the file. Then you can simply skip the batch code (e.g. by getting the line number of the last occurrence of "exit /b" or "goto :eof" using FINDSTR /N.

Code: Select all

@echo off
for /f "delims=:" %%i in ('findstr /nir /c:"\<exit[ ]*/b\>" /c:"\<goto[ ]*:eof\>" "%~fs0"') do set /a EndOfBatch=%%i
for /f %%i in ('type "%~fs0"^|find /c /v ""') do set /a EndOfFile=%%i

setlocal EnableDelayedExpansion
<"%~fs0" (
  for /l %%i in (1 1 %EndOfBatch%) do set /p "="
  for /l %%i in (%EndOfBatch% 1 %EndOfFile%) do (
    set "line=" &set /p "line="
    if defined line echo(!line!
  )
)
endlocal

pause
Exit /B

Help=0
Args=0
Set=0
Defaults=0
Options=0
LastRun=0
SaveRun=0

Regards
aGerman

[Aacini]

I don't see any advantage on using this method vs. a series of SET commands:

Code: Select all

set Help=0
set Args=0
set Set=0
set Defaults=0
set Options=0
set LastRun=0
set SaveRun=0

Antonio

[aGerman]

I don't see any advantage on using this method vs. a series of SET commands

Neither do I. It was only an example to meet the topic

Regards
aGerman

[thefeduke]

I don't see any advantage on using this method vs. a series of SET commands:

Code: Select all

set Help=0
set Args=0
set Set=0
set Defaults=0
set Options=0
set LastRun=0
set SaveRun=0

Antonio

This presumes an intention of setting those values, not creating a test file to process by later code. Both Set /P approaches can handle examples such as:

Code: Select all

111
aaa
222
bbb
333

and:

Code: Select all

The quick brown fox
jumped
without warning

By the way, neither preserves blank lines. aGerman's code discards them and mine erroneously repeats the previous line. I'll work on that because a blank line might be appropriate in an input test file. [Original post was corrected to pass null lines. (I am not clever enough to count spaces with SET /P.)]

John A.

[aGerman]

neither preserves blank lines

That's the reason why you have to undefine the variable before you read the next line. I discarded blank lines because I actually read one line more than the file has.
Simple correction:

Code: Select all

@echo off
for /f "delims=:" %%i in ('findstr /nir /c:"\<exit[ ]*/b\>" /c:"\<goto[ ]*:eof\>" "%~fs0"') do set /a EndOfBatch=%%i+1
for /f %%i in ('type "%~fs0"^|find /c /v ""') do set /a EndOfFile=%%i

setlocal EnableDelayedExpansion
<"%~fs0" (
  for /l %%i in (2 1 %EndOfBatch%) do set /p "="
  for /l %%i in (%EndOfBatch% 1 %EndOfFile%) do (
    set "line=" &set /p "line="
    echo(!line!
  )
)
endlocal

pause
Exit /B
The quick brown fox
jumped
over the lazy dog

without warning

Regards
aGerman

[thefeduke]

aGerman,
I prefer to view mine as the correction of an error and yours as an adjustment for changing requirements. Thanks for the pleasant collaboration.
John A.

[ideleon007]

aGerman, Thank you,
that did exactly what I wanted it to do.
I don't understand it, but will be studying it!
I am planning to run this batch file with elevated rights for any user that feels their
machine may be compromised by malware or whatever.
This is one of the most common locations that Malware likes to hide,
and so, I wanted to clean this area out, then continue to give them the ability to
run a full virus scan on their machine.
This will or may prevent another call for viral threat.
Thanks again for your help,
Israel

[aGerman]

You're welcome! I added some remarks to the code. Also have a look at the Command Index for further reading about FOR /D, RD /S /Q, and DEL /F /Q.

Regards
aGerman