How set name of batch as variable

[darioit]

Hello,

in many script I like to insert this instruction

Code: Select all

IF NOT %errorlevel%==0 CSCRIPT error_script.vbs %name_of_batch% email etc.etc.

How can I set variable %name_of_batch% as launching script name, so I know where this error come from.

Regards

Dario

[tonysathre]

IF NOT %errorlevel%==0 CSCRIPT error_script.vbs %~0 email etc.etc.

Tony

[foxidrive]

I think this is what you mean. As long as the SHIFT command isn't used in the batch script.

Code: Select all

IF NOT %errorlevel%==0 CSCRIPT error_script.vbs "%~nx0" email etc.etc.

[darioit]

oohohooho wonderful, but how do you take this information?

[tonysathre]

I think this is what you mean. As long as the SHIFT command isn't used in the batch script.

Code: Select all

IF NOT %errorlevel%==0 CSCRIPT error_script.vbs "%~nx0" email etc.etc.

Doesn't %~0 expand to the same thing as %~nx0? I know what the n and x do, but I just tested it and it produced the same output. The quotes to catch filenames with spaces is better.

Tony

[foxidrive]

%0 is the full command as entered at the command line (when shift is not used).

If you enter "c:\program files\widget\run.bat" then that entire string will be in %0

So "%~nx0" will only return "run.bat"

[Fawers]

From the CALL command help:

Code: Select all

%~1         - expands %1 and removes any quotes (") on it
%~f1        - expands %1 to a full, qualified path
%~d1       - expands %1 to a drive letter
%~p1       - expands %1 to a path
%~n1       - expands %1 to a file name
%~x1       - expands %1 to a file extension
%~s1       - expands %1 to a short path and file name
%~a1       - expands %1 to file attributes
%~t1         - expands %1 to file date and time
%~z1        - expands %1 to file size

[Fawers]

%0 is the full command as entered at the command line (when shift is not used).

If you enter "c:\program files\widget\run.bat" then that entire string will be in %0

So "%~nx0" will only return "run.bat"

As foxidrive stated, you can combine these letters in order to have only part of the path.
For instance, "%~dpnx1" would return return you the full path of a file. And so would "%~f1".

[darioit]

yes, but how can I know the content of variable %errorlevel%

I mean, during a failure copy of a file, my %errorlevel% is equal to 1, but on shell the error is "Access denied"

How can I grab this information?

[foxidrive]

It depends on your batch file.


You can use something like this, as a simple example.

Code: Select all

@echo off
copy "c:\WINDOWS\system32\cmd.exe" "c:\pagefile.sys" 2>errors.txt
if errorlevel 1 echo Errorlevel is %errorlevel% >>errors.txt
pause 

[darioit]

can I wrote 2> also into a variable?

[Fawers]

can I wrote 2> also into a variable?

I think so, but you'd have to escape the > sign.

Code: Select all

2^>

[foxidrive]

can I wrote 2> also into a variable?

You can wrap the command in a for /F and then get the output into a variable.

Code: Select all

@echo off
for /f "delims=" %%a in ('copy "c:\WINDOWS\system32\cmd.exe" "c:\pagefile.sys" 2^>^&1 ') do set "var=%%a"& goto :goterror
:goterror
echo %var%
pause 

You have to be specific about what you want to do because the code will work above for the copy command, but not for every circumstance.