Don't copy 3 lines to text file?

[Gamer95]

Hi guys!
I was wondering if someone could please help me with this.
I have a txt file called "cat.txt" in the text file i have this:

this
animal
is
a
cat
but
it's
not
my
cat
but
the
neighbors
cat


I looking for the code to find the word "cat" and to grab the line above, the "cat" line and the line below, so three lines.
And copy everything to a textfile, without the three lines.
Like this:

this
animal
is
it's
not
the

A got this code from somewhere and it grab's the three lines but outputs that to the textfile.

Code: Select all

@echo off
setlocal EnableDelayedExpansion
set lastLine=0
< %~1 > %~n1_nocat.txt (for /F "delims=:" %%a in (
              'findstr /N /I /C:"cat" %1') do (
   set /A skip=%%a-lastLine-1, lastLine=%%a+2
   for /L %%i in (1,1,!skip!) do set /P line=
   for /L %%i in (1,1,3) do set /P "line=!line!" & echo/
   echo/
))

Could someone please help?

[foxidrive]

I looking for the code to find the word "cat" and to grab the line above, the "cat" line and the line below, so three lines.
And copy everything to a textfile, without the three lines.
Like this:

this
animal
is
it's
not
the

What you've shown isn't what you've asked, is it?

[ShadowThief]

I looking for the code to find the word "cat" and to grab the line above, the "cat" line and the line below, so three lines.
And copy everything to a textfile, without the three lines.
Like this:

this
animal
is
it's
not
the

What you've shown isn't what you've asked, is it?

He wants to delete the line above each cat, the cat line, and line under each cat.

this
animal
is
a <delete
cat <delete
but <delete
it's
not
my <delete
cat <delete
but <delete
the
neighbors <delete
cat<delete

this
animal
is
it's
not
the

[Gamer95]

Yeah i'm looking for that output in a text file.

this
animal
is
it's
not
the

currently with my script i got this:

a
cat
but

my
cat
but

neighbors
cat
cat

So it's grabbing the correct lines but i need the reverse, sorry for my explanation
Thanks!

[foxidrive]

He wants to delete the line above each cat, the cat line, and line under each cat.

Thanks ShadowThief. You're right and the critical three words "without the three lines" didn't jump out at me.

[foxidrive]

Code: Select all

type cat.txt |findrepl "cat" /o:-1:+1 /v

this
animal
is
it's
not
the


This uses a native Windows batch script called findrepl.bat (by Aacini)
findrepl.bat can be downloaded from: https://www.dropbox.com/s/rfdldmcb6vwi9xc/findrepl.bat
and it can also be found here: viewtopic.php?f=3&t=4697

Place it in the same folder as the batch file, or in a folder that is on the system path.

[Gamer95]

That works great foxidrive thank you,
But can it also work without findrepl.bat?

[ShadowThief]

It's rather long, but it works, provided that none of the lines in the source file have spaces.

Code: Select all

@echo off
setlocal enabledelayedexpansion

if exist %~n1_nocat.txt del %~n1_nocat.txt

for /f "tokens=1,2 delims=:" %%A in ('findstr /N /V /C:" " "%~1"') do (
   set line[%%A]=%%B
   set max_num=%%A
)

for /L %%A in (1,1,!max_num!) do (
   set /a prev_line=%%A-1
   set /a next_line=%%A+1
   if "!line[%%A]!"=="cat" (
      if defined line[!prev_line!] set "line[!prev_line!]="
      set "line[%%A]="
      if defined line[!next_line!] set "line[!next_line!]="
   )
)

for /L %%A in (1,1,!max_num!) do (
   if defined line[%%A] echo !line[%%A]!>>%~n1_nocat.txt
)

[Gamer95]

Thank you both!

[Aacini]

Your code almost did it, just needed a couple small changes:

Code: Select all

@echo off
setlocal EnableDelayedExpansion
set lastLine=0
< %~1 (for /F "delims=:" %%a in ('findstr /N /I /C:"cat" %1') do (
   set /A get=%%a-lastLine-2, lastLine=%%a+1
   for /L %%i in (1,1,!get!) do set /P "line=" & echo !line!
   for /L %%i in (1,1,3) do set /P "line="
)) > %~n1_nocat.txt

Antonio

[Gamer95]

Great Antonio! just great!