How to replace value by variable in for + if loop? Nested exclamation marks

[pstein]

In a previous helpful post in this forum the following batch code (to determine the lenght of file names) was suggested:

Code: Select all

@echo off
setlocal EnableDelayedExpansion

for /R H:\archive %%f in (*.*) do (
   set "name=%%f"
   if "!name:~100,1!" neq "" (
      for /L %%i in (100,1,500) do if "!name:~%%i,1!" neq "" set /A len=%%i+1
      echo !len!: !name!
   )
)

It works. Unfortunately one of the parameters inside the for loop is a fix value (100).

Now I search for a way to´parameterize it. However the following does NOT work:

Code: Select all

@echo off
setlocal EnableDelayedExpansion
set threshold=100
for /R H:\archive %%f in (*.*) do (
   set "name=%%f"
   if "!name:~!threshold!,1!" neq "" (
      for /L %%i in (:~!threshold!,1,500) do if "!name:~%%i,1!" neq "" set /A len=%%i+1
      echo !len!: !name!
   )
)

I guess because DOS does not accept nested exclamation marks
How else should I rewrite the first code to get it working?

Thank you
Peter

[foxidrive]

Code: Select all

@echo off
call :routine 5      
pause
goto :eof
:routine
setlocal EnableDelayedExpansion
for /R "H:\archive" %%f in (*.*) do (
   set "name=%%f"
   if "!name:~%1,1!" neq "" (
      for /L %%i in (%1,1,500) do if "!name:~%%i,1!" neq "" set /A len=%%i+1
      echo !len!: !name!
   )
)

[pstein]

Thank you for the solution.
But is this all possible without a (sub)routine/procedure?

[Squashman]

I am not understanding why you are using delayed expansion for the threshold variable?

[foxidrive]

Good point.

This is wrong too: :~!threshold!

[pstein]

Ok, seems to work

Thank you