Question for FOR /F.

[einstein1969]

why this not work how expected?

Code: Select all

@echo off
FOR /F "usebackq delims=;" %%1 IN ('aa; bb; c c') DO ECHO %%1

result

Code: Select all

aa bb c c

Einstein1969

[IcarusLives]

I'm not sure why, but these also do not work as expected

Code: Select all

@echo off
FOR /F "usebackq delims=;" %%1 IN (`echo aa; bb; c c`) DO ECHO %%1

Output:
aa bb cc

Code: Select all

@echo off
FOR /F "usebackq tokens=* delims=;" %%1 IN ('aa; bb; c c') DO ECHO %%1

Output:
aa bb cc

Code: Select all

@echo off
FOR /F "usebackq tokens=1 delims=;" %%1 IN ('aa; bb; c c') DO ECHO %%1

Output:
aa bb cc

Code: Select all

@echo off
FOR /F "usebackq tokens=2 delims=;" %%1 IN ('aa; bb; c c') DO ECHO %%1

Output:

[dbenham]

It is absolutely giving the expected behavior

Everything is explained by the fact that any string of consecutive unquoted and unescaped token delimiters (<space> <tab> , ; = <0xFF>) appearing within IN() clause is converted into a single space. And this conversion occurs before FOR /F tries to parse any tokens.

Code: Select all

@echo off
for /f "usebackq delims=" %%A in (',,,;;;;====     aa,,,;;;;====     bb,,,;;;;====     c,,,;;;;====     c,,,;;;;====     ') do echo [%%A]

--RESULTS--

Code: Select all

[ aa bb c c ]

If you really insist on using USEBACKQ, then you can escape the ;

Code: Select all

@echo off
FOR /F "usebackq delims=;" %%1 IN ('aa^; bb^; c c') DO ECHO %%1

--RESULTS--

Code: Select all

aa

Actually, you should escape all the token delimiters

Code: Select all

@echo off
FOR /F "usebackq delims=;" %%1 IN ('aa^;^ bb^;^ c^ c') DO ECHO %%1

Failure to do so could expose this nasty bug on XP

But why use USEBACKQ
You are simply making life difficult for yourself. All you need to do is drop USEBACK and use double quotes to enclose the string:

Code: Select all

@echo off
FOR /F "delims=;" %%1 IN ("aa; bb; c c") DO ECHO %%1

Prevalent use of USEBACKQ is one of my pet peeves. I've thought long and hard, and done a number of experiments, and the only time USEBACKQ is necessary is when your FOR /F should read a file whose path includes spaces or poison characters, and then you are safely using double quotes within the IN() clause.

There is no reason to ever use USEBACKQ in any other situation.

USEBACKQ - Just say NO! (unless you are reading file content)


Dave Benham

[einstein1969]

thanks Dave!