If conditionals - not working

[SIMMS7400]

Hi Folks -

This may be so simple I'm over looking things, but I'm having trouble with if logic using "IF DEFINED" syntax.

For instance, I would like for this to work:

Code: Select all

IF DEFINED ERR_FILE IF DEFINED FDMEE_ERR (
	SET "SW_ATTACH=%LOGFILE%|%ERR_FILE%|%INTRAPATH%%MONTHPOV%%YEARPOV%_%MAXFILE%"
	MOVE /Y "*.log" "%INTRAPATH%" >nul 2>&1
) ELSE IF NOT DEFINED ERR_FILE IF DEFINED FDMEE_ERR (
	SET "SW_ATTACH=%LOGFILE%|%INTRAPATH%%MONTHPOV%%YEARPOV%_%MAXFILE%"
) ELSE (
	SET "SW_ATTACH=%LOGFILE%"
)

But it does not, so therefore, I need to use this format:

Code: Select all

SET "SW_ATTACH=%LOGFILE%"

IF DEFINED ERR_FILE IF DEFINED FDMEE_ERR (
	SET "SW_ATTACH=%LOGFILE%|%ERR_FILE%|%INTRAPATH%%MONTHPOV%%YEARPOV%_%MAXFILE%"
	MOVE /Y "*.log" "%INTRAPATH%" >nul 2>&1
)
IF NOT DEFINED ERR_FILE IF DEFINED FDMEE_ERR (
	SET "SW_ATTACH=%LOGFILE%|%INTRAPATH%%MONTHPOV%%YEARPOV%_%MAXFILE%"
)

Can anyone explain why? Thanks!

[aGerman]

This is equivalent to your first code and should explain the behavior:

Code: Select all

IF DEFINED ERR_FILE (
  IF DEFINED FDMEE_ERR (
    SET "SW_ATTACH=%LOGFILE%|%ERR_FILE%|%INTRAPATH%%MONTHPOV%%YEARPOV%_%MAXFILE%"
    MOVE /Y "*.log" "%INTRAPATH%" >nul 2>&1
  ) ELSE (
    IF NOT DEFINED ERR_FILE (
      IF DEFINED FDMEE_ERR (
        SET "SW_ATTACH=%LOGFILE%|%INTRAPATH%%MONTHPOV%%YEARPOV%_%MAXFILE%"
      ) ELSE (
        SET "SW_ATTACH=%LOGFILE%"
      )
    )
  )
)

Steffen

[SIMMS7400]

Hi Steffan -

Thank you very much!

I'm following. Is there a better way to consutruct than option #2 I outlined above?

I"ll keep playing around with it - thanks again!

[penpen]

You could check if FDMEE_ERR is defined first:

Code: Select all

SET "SW_ATTACH=%LOGFILE%"

IF DEFINED FDMEE_ERR IF DEFINED ERR_FILE (
	SET "SW_ATTACH=%LOGFILE%|%ERR_FILE%|%INTRAPATH%%MONTHPOV%%YEARPOV%_%MAXFILE%"
	MOVE /Y "*.log" "%INTRAPATH%" >nul 2>&1
) else (
	SET "SW_ATTACH=%LOGFILE%|%INTRAPATH%%MONTHPOV%%YEARPOV%_%MAXFILE%"
)

penpen

[SIMMS7400]

Thank you, all!