how to read file name with spaces?

[lalat06bag]

Below code is to convert all pdf files to txt.

Code: Select all

@echo off &setlocal
set "pdfToText=C:\Users\u595142\Desktop\xpdf32\pdftotext.exe" & rem source for the pdftotext exe
set "allPdfFiles=C:\Users\u595142\Desktop\allPdfFiles" & rem source pdf folder
set "allTxtFiles=C:\Users\u595142\Desktop\allTxtFiles" & rem source txt folder
if not exist "%allTxtFiles%" mkdir "%allTxtFiles%"

for /f %%v in ('dir /b %allPdfFiles%\*.pdf') do (
  "%pdfToText%" "%allPdfFiles%\%%v" "%allTxtFiles%\%%~nv.txt" >NUL 2>&1 || echo Error converting %%v
)

endlocal
exit/B

It could not read the filenames with space.
If fine name is XXXX_QRRPS Tran book - 0utgoing-en-in_2018-02-09T024757245Z.pdf, it reads XXXX_QRRPS.
can any one please see?

[Squashman]

Turn ECHO ON at the top of your script and show us all the console output processing that one specific file.

[lalat06bag]

Please see now.

for /f %%v in ('dir /b %allPdfFiles%\*.pdf') do (
"%pdfToText%" "%allPdfFiles%\%%v" "%allTxtFiles%\%%~nv.txt" >NUL 2>&1 || echo Error converting %%v
echo %pdfToText%
echo %allPdfFiles%\%%v
echo %allTxtFiles%\%%~nv.txt
pause
)

Error converting XXXX_QRRPS
C:\Users\u595142\Desktop\xpdf32\pdftotext.exe
C:\Users\u595142\Desktop\allPdfFiles\XXXX_QRRPS
C:\Users\u595142\Desktop\allPdfFiles\XXXX_QRRPS.txt
Press any key to continue

[Squashman]

Please see now.

That is not what I asked for.

[Squashman]

Two options for you.

Code: Select all

for /f "delims=" %%v in ('dir /b %allPdfFiles%\*.pdf') do (
  "%pdfToText%" "%allPdfFiles%\%%v" "%allTxtFiles%\%%~nv.txt" >NUL 2>&1 || echo Error converting %%v
)

Code: Select all

for %%v in ("%allPdfFiles%\*.pdf") do (
  "%pdfToText%" "%%~v" "%allTxtFiles%\%%~nv.txt" >NUL 2>&1 || echo Error converting %%v
)

[lalat06bag]

Thank you. This is perfect.