DosTips.com

Code: Select all

@echo off
rem The string replacement of environment variable is used, so we need to enable the extensions.
rem The delayed expansion must be switched off to avoid the delayed expansion of for/f-loop variable %%a.
setlocal enableExtensions disableDelayedExpansion
rem search string to be replaced
set "replace=something"
rem replacement string
set "replaced=different"

set "source=Source.txt"
set "target=Target.txt"

rem redirect all output of the for/f-loop to the target file
(
	rem findstr /N "^" "%source%" will print all lines with line numbers.
	rem The search string is the regular expression "^", which represents a line start.
	rem The option "/N" will prepend the line number and a double colon,
	rem dividing the line number from the line content.
	
	rem The for/f-loop iterates over all lines, the findstr statement will produce.
	rem Here digits are treated as delimiters (which menas they are filtered out),
	rem so the loop iterates over all lines prepended with exact one double colon.
	
	for /F "tokens=* delims=0123456789" %%a in ('findstr /N "^" "%source%"') do (
		rem In order to use string replacement of environment variable, we need to store 
		rem the content of the for loop variable into an environment variable.
		set "line=%%a"
		
		rem we want to change the variable line, so we need delayed expansion within the actual for-block
		setlocal enableDelayedExpansion
		rem first remove the double colon, such that we work on the original line
		set "line=!line:~1!"
		
		rem if the line is not empty
		if defined line (
			rem overwrite the line variable with the result of the string replacement
			set "line=!line:%replace%=%replaced%!"
		)
		
		rem echo the result
		echo(!line!
		
		rem leave delayed expanded context
		endlocal
	)
) >"%target%"

goto :eof