DosTips.com

Posted: **16 Oct 2024 23:00**

I have 1.cmd:

@call 2.cmd
@echo HERE-1.cmd

and I have 2.cmd

Code: Select all

@echo off
for %%f in (a.a b.b c.c) do call :DOIT "%%f"

echo END-2.cmd
goto :EOF

:DOIT
set errlev=1
if not "%errlev%"=="0" echo ERROR %1.&exit /b

echo TOO FAR
goto :EOF

Output:

Code: Select all

c:\>
ERROR "a.a".
ERROR "b.b".
ERROR "c.c".
END-2.cmd
HERE-1.cmd
c:\>

I want to exit 2.cmd when first error (a.a) occurs. If I just use EXIT 1.cmd quits - I don't want that.

Please help.

Thanks.

Saso

Posted: **17 Oct 2024 02:05**

You can use a small function to exit only the current batch

Code: Select all

:exit-current-batch
for /L %%# in (0 1 40) DO (
    (goto) 2> NUL
    call set "_tmp=%%0"
    call set "_tmp=%%_tmp:~0,1%%"
    call set "_tmp=%%_tmp::=%%"
    if defined _tmp (
        REM Current Batch entry found
        exit /b
    )
)
exit /b

Just use CALL :exit-current-batch or GOTO :exit-current-batch, and it will return to the caller batch file.

Posted: **17 Oct 2024 02:38**

Thanks.

Saso

DosTips.com

How to break from a .cmd?

How to break from a .cmd?

Re: How to break from a .cmd?

Re: How to break from a .cmd?