DosTips.com

Code: Select all

:main
    @echo off
   cls
   setlocal enableDelayedExpansion

::   drive set
   set "driveSet=X Y Z"
   set "hdds=%driveSet: =%"
   for %%a in (0 1 2) do set "hdd[%%a]=!hdds:~%%a,1!"

   set "directories=directories.txt"
   set "files=files.txt"
   set "tmpFile=temp.txt"
   set "log=log.txt"



::   build %files% and %directories% to verify, eliminating multiple entries
   (rem:)>"%log%"

   (
      echo building %directories%

      (for %%a in (0 1 2) do for /f "tokens=1,* delims=:" %%b in ('dir !hdd[%%a]!:\ /A:D /B /O:N /S') do echo %%c) > "%directories%"
      sort "%directories%" /O "%tmpFile%"
      (
         set "lastLine="
         for /f "tokens=* delims=" %%b in ('findstr "^" "%tmpFile%"') do (
            if not "%%b" == "!lastLine!" (
               echo %%~b
               set "lastLine=%%~b"
            )
         )
      ) > "%directories%"

      del "%tmpFile%"
      echo building %directories%: finished
   ) >> "%log%"

   (
      echo building %files%

      (for %%a in (0 1 2) do for /f "tokens=1,* delims=:" %%b in ('dir !hdd[%%a]!:\ /A:-D /B /O:N /S') do echo %%c) > "%files%"
      sort "%files%" /O "%tmpFile%"
      (
         set "lastLine="
         for /f "tokens=* delims=" %%a in ('findstr "^" "%tmpFile%"') do (
            if not "%%a" == "!lastLine!" (
               echo %%~a
               set "lastLine=%%~a"
            )
         )
      ) > "%files%"
      del "%tmpFile%"

      echo building %files%: finished
   ) >> "%log%"


::   check for directory-file-name-collision and missing directories, create it if posssible
   (
      echo checking directories

      set "errors="
      set "arg="
      for /f "tokens=* delims=" %%b in ('findstr "^" "%directories%"') do (
         set "args="
         for %%a in (0 1 2) do (
            for %%c in ("!hdd[%%a]!:%%~b") do (
               if not exist %%c md %%c
               if not exist %%c (   
                  set "args=!args!F"
               ) else (
                  set "arg=%%~ac"
                  set "args=!args!!arg:~0,1!"
               )
            )
         )

         if not "!args:F=!" == "!args!" (
            echo checking directories: could not create missing diretory: %%c
            set "errors=true"
            set "args=!args:F=!"
         )

         if defined args if not "!args:D=!" == "" (
            echo checking directories: detected directory-file-name collision: %%b
            set "errors=true"
         )
      )

      if defined errors set "errors=with errors"
      echo checking directories: finished !errors!
   ) >> "%log%"

   if defined errors (
      echo There were errors, that cannot be fixed automatically.
      echo See %log% for further informations.
      exit /b 1
   )

::   checking files, create files if needed and possible
::   using coded ok in positive logic: bit 2: ok20, bit 1: ok12, bit 0: ok01
::   source: space(ok) --> driveSet
   set "source(1)=%hdd[1]%"
   set "source(2)=%hdd[2]%"
   set "source(3)=%hdd[2]%"
   set "source(4)=%hdd[0]%"
   set "source(5)=%hdd[0]%"

::   target: space(ok) --> driveSet
   set "target(1)=%hdd[2]%"
   set "target(2)=%hdd[0]%"
   set "target(3)=%hdd[0]%"
   set "target(4)=%hdd[1]%"
   set "target(5)=%hdd[1]%"

   (
      echo checking files

      for /f "tokens=* delims=" %%b in ('findstr "^" "%files%"') do (
         set "ok=7"

         if not exist %hdd[0]%:%%b set /A "ok&=2"
         if not exist %hdd[1]%:%%b set /A "ok&=4"
         if not exist %hdd[2]%:%%b set /A "ok&=1"

         if !ok! GEQ 4 (
            fc /A /B "%hdd[0]%:%%b" "%hdd[2]%:%%b" > nul
            if errorlevel 1 set "ok&=3"
         )

         set /A "check=!ok!&2"
         if !check! == 2 (
            fc /A /B "%hdd[1]%:%%b" "%hdd[2]%:%%b" > nul
            if errorlevel 1 set "ok&=5"
         )

         if !ok! == 1 (
            fc /A /B "%hdd[0]%:%%b" "%hdd[1]%:%%b" > nul
            if errorlevel 1 set "ok&=6"
         )

         if not !ok! == 7 (
            if !ok! GTR 0 (
               for %%c in (!ok!) do (
                  set "source=!source(%%c)!:%%b"
                  set "target=!target(%%c)!:%%b"
               )

               if not exist !target! (rem:)>"!target!"
               xcopy %source% %target% /V /H /R /K /O /X /Y > nul
               if errorlevel 1 fc /A /B %source% %target% > nul
               if errorlevel 1 (
                  echo checking files: updating failed: source: %source%
                  echo checking files: updating failed: target: %source%
                  set "errors=true"
               )
            ) else (
               echo checking files: unverifiable %%b
               set "errors=true"
            )
         )
      )

      if defined errors set "errors=with errors"
      echo checking files: finished !errors!
   ) >> "%log%"

   if defined errors (
      echo There were errors, that cannot be fixed automatically.
      echo See %log% for further informations.
      exit /b 1
   )

   echo Finished software raid 1.3 update successfully.
   goto :eof

Code: Select all

:: A:\F ?= B:\F read two times:
fc /b A:\F B:\F

:: B:\F ?= C:\F read two times:
fc /b B:\F C:\F

:: (not A:\F == B:\F) and (not B:\F == C:\F) because B:\F differs, then read another 2 times
fc /b A:\F C:\F

Code: Select all

:: case 1: compare {A, B}, compare {A, C}
:: case 2: compare {A, B}, compare {B, C}
:: case 3: compare {A, C}, compare {A, B}
:: case 4: compare {A, C}, compare {C, B}
:: case 5: compare {B, C}, compare {B, A}
:: case 6: compare {B, C}, compare {C, A}
:: so all cases are equivalent, you have to do this: (just shown for case 1:
fc /b A B
fc /b A C