Problem with loop and composited new variable

[[newbie]]

Hi
I would like to add a wow_ to the old variable set "oldV=aaa bbb ccc ddd"
and the finished variable should look like set "newV=wow_aaa wow_bbb wow_ccc wow_ddd"
I get it only to:

Code: Select all

@echo off 
Setlocal EnableDelayedExpansion
set "addV=wow_"
set "oldV=aaa bbb ccc ddd"
for %%i in (%oldV%) do (
      set "newV=!addV!%%i"
      echo !newV!
      REM to new assemble...
)

How can i get the new variable composited?

[foxidrive]

Here is one way:

Code: Select all

@echo off
set "addV=wow_"
set "oldV=aaa bbb ccc ddd"
for %%a in (%oldV%) do call set "newv=%%newv%% %addV%%%a"
set "newv=%newv:~1%"
echo %newV%
pause

[Squashman]

Code: Select all

@echo off 
Setlocal EnableDelayedExpansion
set "addV=wow_"
set "oldV=aaa bbb ccc ddd"
for %%i in (%oldV%) do (
      set "newV=!newV!!addV!%%i "
      echo !newV!
      REM to new assemble...
)

[[newbie]]

Thx4Help

[Yury]

Code: Select all

@echo off
setlocal enabledelayedexpansion
set "oldV=aaa bbb ccc ddd"
set "addV=wow_"
set "newV=%addV%!oldV: = %addV%!"
echo %newV%

[[newbie]]

Code: Select all

@echo off
setlocal enabledelayedexpansion
set "oldV=aaa bbb ccc ddd"
set "addV=wow_"
set "newV=%addV%!oldV: = %addV%!"
echo %newV%

Thx, very nice implementation.