Page 1 of 1
Problem with loop and composited new variable
Posted: 04 Sep 2015 06:52
by [newbie]
Hi
I would like to add a
wow_ to the old variable
set "oldV=aaa bbb ccc ddd"and the finished variable should look like
set "newV=
wow_aaa wow_bbb wow_ccc wow_ddd"
I get it only to:
Code: Select all
@echo off
Setlocal EnableDelayedExpansion
set "addV=wow_"
set "oldV=aaa bbb ccc ddd"
for %%i in (%oldV%) do (
set "newV=!addV!%%i"
echo !newV!
REM to new assemble...
)
How can i get the new variable composited?
Re: Problem with loop and composited new variable
Posted: 04 Sep 2015 07:04
by foxidrive
Here is one way:
Code: Select all
@echo off
set "addV=wow_"
set "oldV=aaa bbb ccc ddd"
for %%a in (%oldV%) do call set "newv=%%newv%% %addV%%%a"
set "newv=%newv:~1%"
echo %newV%
pause
Re: Problem with loop and composited new variable
Posted: 04 Sep 2015 07:05
by Squashman
Code: Select all
@echo off
Setlocal EnableDelayedExpansion
set "addV=wow_"
set "oldV=aaa bbb ccc ddd"
for %%i in (%oldV%) do (
set "newV=!newV!!addV!%%i "
echo !newV!
REM to new assemble...
)
Re: Problem with loop and composited new variable
Posted: 04 Sep 2015 07:11
by [newbie]
Thx4Help
Re: Problem with loop and composited new variable
Posted: 04 Sep 2015 09:06
by Yury
Code: Select all
@echo off
setlocal enabledelayedexpansion
set "oldV=aaa bbb ccc ddd"
set "addV=wow_"
set "newV=%addV%!oldV: = %addV%!"
echo %newV%
Re: Problem with loop and composited new variable
Posted: 06 Sep 2015 09:44
by [newbie]
Yury wrote:Code: Select all
@echo off
setlocal enabledelayedexpansion
set "oldV=aaa bbb ccc ddd"
set "addV=wow_"
set "newV=%addV%!oldV: = %addV%!"
echo %newV%
Thx, very nice implementation.