DosTips.com

Code: Select all

@echo off
setlocal EnableDelayedExpansion

rem Load data from file2.csv into "row2" array
echo Loading data from file2.csv, please wait...
set "i=0"
< NUL (for /F "skip=1 tokens=1,2* delims=," %%a in (file2.csv) do (
   set /A i+=1
   set "row2[!i!]=%%a,%%b,%%c"
   set /P "=!i!,"

   rem Separate Particulars column in slash-delimited fields into "part" array
   rem that contain the records in row2 that contain each one
   set "part=%%b"
   set "start="
   for %%p in ("!part:/=" "!") do (
      if not defined start (
         set "start=%%p"
      ) else (
         set "part[%%p]=!part[%%p]! !i! "
      )
   )
))
cls

rem Process the file1.csv

del Reconresult.csv 2>NUL
for /F "skip=1 tokens=1,2* delims=," %%a in (file1.csv) do (

   rem Show each record in file1.csv
   echo %%a,%%b,%%c

   rem Separate Particulars column in slash-delimited fields,
   rem test if a matching element exist in part/row2 arrays
   rem and show a menu with all matching row2's
   set "part=%%b"
   set "start="
   set "i=0"
   for %%p in ("!part:/=" "!") do (
      if not defined start (
         set "start=%%p"
      ) else if defined part[%%p] (

         rem There are at least one slash-delimited field match; list all of them
         for %%n in (!part[%%p]!) do (
            set /A i+=1
            echo !i!:   !row2[%%n]!
            set "rec[!i!]=%%n,%%p"
         )

             rem Separate the slash-delimited field in two words
      ) else for /F "tokens=1,2" %%x in (%%p) do (
         if defined part["%%x %%y"] (

            rem There are at least one partial two-words field match
            for %%n in (!part["%%x %%y"]!) do (
               set /A i+=1
               echo !i!:   !row2[%%n]!
               set "rec[!i!]=%%n,"%%x %%y""
            )
         ) else if defined part["%%x"] (

            rem There are at least one partial one-word field match
            for %%n in (!part["%%x"]!) do (
               set /A i+=1
               echo !i!:   !row2[%%n]!
               set "rec[!i!]=%%n,"%%x""
            )
         )
      )
   )

   rem If there were matches, let the user to select one
   if !i! equ 0 (
      echo No match
   ) else (
      set /P "match=Select match, 0 for no match: "
      (if !match! gtr 0 for /F %%m in ("!match!") do for /F "tokens=1,2 delims=," %%i in ("!rec[%%m]!") do (
         rem Output the records from file1.csv and file2.csv into result
         echo %%a,%%b,%%c
         echo !row2[%%i]!
         echo/
         rem Remove the elements from row2/part
         set "row2[%%i]="
         set "part[%%j]=!part[%%j]: %%i = !"
      )) >> Reconresult.csv
   )

   echo/
)