Verify a string exists within another string?

[djangofan]

If I have a string , containing all of my concatenated args to my batch script, that looks like this:

"-debug -verbose -normi -homedir -repo"

Is there a way to verify that "-verbose" exists within that string without using a space-delimmetted FOR loop to compare each token? Basically, I want a function that works like so IF it is at all possible :

Code: Select all

@ECHO off
CALL :MYFUNCTION "-verbose"
IF %ERRORLEVEL%==0 ECHO Success^^!
pause
:MYFUNCTION
[do something here]
EXIT /B %ERRORLEVEL%

So, in other words, I suppose I am looking for something like FINDSTR.exe that works on a string rather than on a file.

[dbenham]

You can use string search and replace to do a case insensitive search. Replace your search term with nothing, and see if the result matches the original:

Code: Select all

set "str=-debug -verbose -normi -homedir -repo"
if "%str:-debug=%" neq "%str%" (echo -verbose found) else (echo -verbose not found)

Dave Benham

[djangofan]

Thank you thank you thank you! I was looking for an idea like that one.

[Squashman]

Love Dave's code with the String replacement.

But yes in theory you could use Findstr and look at the errorlevel.

Code: Select all

E:\batch files>set "str=-debug -verbose -normi -homedir -repo"
E:\batch files>echo %str% | findstr /c:"-verbose"
-debug -verbose -normi -homedir -repo

E:\batch files>echo %errorlevel%
0

E:\batch files>echo %str% | findstr /c:"-verboses"

E:\batch files>echo %errorlevel%
1

[dbenham]

The FINDSTR search is case sensitive by default.

Since you probably don't want to see the FINDSTR output, you might want to redirect the output to nul:

Code: Select all

echo %str%|findstr /c:"-verbose" >nul

Dave Benham

[Squashman]

The FINDSTR search is case sensitive by default.

Since you probably don't want to see the FINDSTR output, you might want to redirect the output to nul:

Code: Select all

echo %str%|findstr /c:"-verbose" >nul

Dave Benham

That is one of things I like about this forum. The attention to detail everyone has with code.
Thanks Dave for pointing that out.

[djangofan]

Thanks Squashman and dbenham . I wouldn't have imagined 2 different ways of doing it. Thank you!

[Aacini]

You may also use my %SET/A% macro with TEST(strConst IN strVar) function this way:

Code: Select all

set argv=-debug -verbose -normi -homedir -repo
%set/a% pos=TEST("-verbose" IN argv)
if %pos% gtr 0 (echo -verbose found at position %pos%) else echo -verbose not found

Or you may directly use TEST function with no %SET/A% macro:

Code: Select all

call TEST "-verbose" IN argv pos=
if %pos% gtr 0 (echo -verbose found at position %pos%) else echo -verbose not found

Both SET/A macro and TEST function are described in this topic.

[alan_b]

You can use string search and replace to do a case insensitive search. Replace your search term with nothing, and see if the result matches the original:

Code: Select all

set "str=-debug -verbose -normi -homedir -repo"
if "%str:-debug=%" neq "%str%" (echo -verbose found) else (echo -verbose not found)

Dave Benham

I like it, quite a lot.
I have two immediate uses for it,
but for one use it has a killer bug that I had to fix.
It MIGHT be relevant to this topic also.

I have two specific command words, e.g. "DoThis" and "DoThat".
I have a file with 8,000 lines,
and I need to reject each line which starts with some other word,
e.g. words such as "dothis DOTHAT DoNowt Dot that"

In the following my first attempt was Demo1,
which worked correctly for the first three words,
but the last two illegal words were partial matches for legal words and were wrongly validated.

My second attempt Demo2 uses # as boundary markers for the legal words, and all the results are good.
You can of course use any boundary markers that do not appear within the legal words.

Code: Select all

@echo off & setlocal EnableDelayedExpansion
call :demo1 "DoThis DoThat" "dothis DOTHAT DoNowt Dot that"
call :demo2 "#DoThis# #DoThat#" "dothis DOTHAT DoNowt Dot that"
:pause
exit/b

:Demo1
set str=%~1
echo( & echo( validating random {%~2} against legal {%~1}
for %%a in (%~2) do (
  if "!str:%%a=!"=="%str%" (echo rejected   %%a) else (echo validated  %%a )
)
exit /b

:Demo2
set str=%~1
echo( & echo( validating random {%~2} against legal {%~1}
for %%a in (%~2) do (
  if "!str:#%%a#=!"=="%str%" (echo rejected   %%a) else (echo validated  %%a )
)
exit /b

Code results :-

Code: Select all

E:\T\CCleaner\v313\WinApp_2>x

 validating random {dothis DOTHAT DoNowt Dot that} against legal {DoThis DoThat}
validated  dothis
validated  DOTHAT
rejected   DoNowt
validated  Dot
validated  that

 validating random {dothis DOTHAT DoNowt Dot that} against legal {#DoThis# #DoThat#}
validated  dothis
validated  DOTHAT
rejected   DoNowt
rejected   Dot
rejected   that

E:\T\CCleaner\v313\WinApp_2>

Regards
Alan

[djangofan]

@Aacini - just when I thought I had mastered batch scripts, the rabbit hole gets even deeper. Thanks for the reference to Macros.