For loop to hit each user on a machine

[motanicus]

This was convoluted - I think I got it right. It removes the \users\username\

Code: Select all

@echo off
for %%a in ("%userprofile%") do (
for /f "delims=" %%b in ('dir "%%~dpa" /ad /b') do (
pushd "%%~dpa\%%b"
for /f "delims=" %%c in ('dir *.ost *.pst  /a-d /b /s 2^>nul ') do (
call :next "%%~dpa%%b" "%%~dpc" "%%c"
)
popd
)
)
pause
goto :EOF

:next
set "var1=%~1"
set "var2=%~2"
call set "var3=%%var2:%var1%=%%"
md "%~1\AppData\Local\Microsoft\Outlook\Backup\%var3%" 2>nul
move "%~3" "%~1\AppData\Local\Microsoft\Outlook\Backup\%var3%" >nul

Awesome, I will check this out tomorrow on my test box and let ya know if it works out.
thanks!

[foxidrive]

Just so you are aware, that version actually moves the files.

This version should create and move the temp files.

Code: Select all

@echo off
for %%a in ("%userprofile%") do (
for /f "delims=" %%b in ('dir "%%~dpa" /ad /b') do (
pushd "%%~dpa\%%b"
for /f "delims=" %%c in ('dir *.ost *.pst  /a-d /b /s 2^>nul ') do (
call :next "%%~dpa%%b" "%%~dpc" "%%c"
)
popd
)
)
pause
goto :EOF

:next
set "var1=%~1"
set "var2=%~2"
call set "var3=%%var2:%var1%=%%"
type nul> "%~3.movetest"
md "%~1\AppData\Local\Microsoft\Outlook\Backup\%var3%" 2>nul
move "%~3.movetest" "%~1\AppData\Local\Microsoft\Outlook\Backup\%var3%" >nul

[motanicus]

ha one more funky thing:
C:\Users\username\AppData\Local\Microsoft\Outlook\Backup\AppData\Local\Microsoft\Outlook\Backup\AppData\Local\Microsoft\Outlook
is now the new backup location
otherwise this is working perfectly (removes the OST/PST file from original source)

[foxidrive]

ha one more funky thing:
C:\Users\thoopes\AppData\Local\Microsoft\Outlook\Backup\AppData\Local\Microsoft\Outlook\Backup\AppData\Local\Microsoft\Outlook
is now the new backup location
otherwise this is working perfectly (removes the OST/PST file from original source)

It doesn't use that location here. Try removing all files/folders from here and running it again.
C:\Users\thoopes\AppData\Local\Microsoft\Outlook\Backup


EDIT: Maybe if an earlier folder contained some backups then it will move them again.