Strange output in call echo %var%: "This fail"

[Aacini]

I found a strange behaviour when I assemble an output string with nested percent signs that I later expanded via "call echo %var%":

Code: Select all

@echo off
setlocal EnableDelayedExpansion

set "answer=First SecondThird "
set "output=The answer is: %%answer:~^!num^!,6%%"
set /A num=(%random% %% 3) * 6

echo The base output:
echo "%output%"

echo The strange call output:
call echo "%output%"

The output:

Code: Select all

The base output:
"The answer is: %answer:~0,6%"
The strange call output:
This fail

I assume this error is caused by the parsing phases. Is there any way to achieve this output?

Antonio

[jeb]

Hi Aacini,

I tested it (Win7x64) but I get the expected outputs.

The base output:
"The answer is: %answer:~6,6%"
The strange call output:
"The answer is: Second"

C:\temp>test
The base output:
"The answer is: %answer:~6,6%"
The strange call output:
"The answer is: Second"

C:\temp>test
The base output:
"The answer is: %answer:~0,6%"
The strange call output:
"The answer is: First "

C:\temp>test
The base output:
"The answer is: %answer:~0,6%"
The strange call output:
"The answer is: First "

Did you run it in a fresh cmd window?
Did you get the text "This fail", a syntax error or nothing?

[aGerman]

I don't have any problems on Win7 x86.

Code: Select all

C:\>test.bat
The base output:
"The answer is: %answer:~6,6%"
The strange call output:
"The answer is: Second"

C:\>test.bat
The base output:
"The answer is: %answer:~6,6%"
The strange call output:
"The answer is: Second"

C:\>test.bat
The base output:
"The answer is: %answer:~0,6%"
The strange call output:
"The answer is: First "

C:\>

[Aacini]

Wow! I use Windows 8.1 64-bits Spanish version. I restarted the OS, open a new cmd.exe session and test my program. This is the output:





Antonio

[jeb]

Then you simply should delete your echo.bat file

[OperatorGK]

Then you simply should delete your echo.bat file

I think it's external program somewhere in %PATH%. Nobody in clear mind will create such a batch file!
To distinguish them, append "pause" to the end. If it's echo.bat, program won't pause, but if it's echo.exe, it will pause .

[Aacini]

Then you simply should delete your echo.bat file

Yes of course!!!! This is the reason!

Thanks, jeb

Antonio

EDIT: PS - I created the echo.bat file precisely to test a certain point some time ago, and forgot it...

[OperatorGK]

Then you simply should delete your echo.bat file

Yes of course!!!! This is the reason!

Thanks, jeb

Antonio

Please explain why you created this file. I thought nobody familiar with cmd.exe would do so.
What is the point?

[jeb]

Yes of course!!!! This is the reason!

I only guess it, as I have the same problems with incredibly behaviour so many times before

Now I use in my "echo.bat" and "set.bat" files always code like this

Code: Select all

@echo **** This is %0 ****

Please explain why you created this file. I thought nobody familiar with cmd.exe would do so.
What is the point?

Aacini is one of the persons who are very familiar with cmd.exe

And this is the way to test how CALL works or which echo style creates disk accesses.

[dbenham]

Now I use in my "echo.bat" and "set.bat" files always code like this

Code: Select all

@echo **** This is %0 ****

You might try the following instead:

Code: Select all

@echo **** This is %~f0 ****

Dave Benham

[OperatorGK]

Aah, thank you. I remember topic where you try to find safe echo method.

[Meerkat]

Hope this helps...

Code: Select all

@echo off
set "var=This worked"
set "caller=var"

call :do-the-thing echo %%%caller%%%
pause>nul
exit /b

:do-the-thing
%* & goto :EOF

Output:

Code: Select all

This worked