files from different folder dropped into batch file?

[jamjoh]

Hi I cant figure this one out. If I drop file into batch from same folder it works fine, but not file from different folder. I dont know how to change working directory path or something??? Here is my bat file;

Code: Select all

@echo on
cd "F:\PUBLIC\shared\Lathe\ScrewMills\ShopAccess\CNC Programs\WeinCAD Programs"
copy "%~nx1" "F:\PUBLIC\shared\Lathe\ScrewMills\temp"
DEL/Q "F:\PUBLIC\shared\Lathe\ScrewMills\ShopAccess\CNC Programs\CURRENT CNC PROGRAM\AEI\*.000"
move "F:\PUBLIC\shared\Lathe\ScrewMills\temp\*.*" "F:\PUBLIC\shared\Lathe\ScrewMills\ShopAccess\CNC Programs\Transfer NC PROGRAM\AEI" 
dir/w /b /a-d "F:\PUBLIC\shared\Lathe\ScrewMills\ShopAccess\CNC Programs\CURRENT CNC PROGRAM\AEI" > "F:\PUBLIC\shared\Lathe\ScrewMills\AEI.log"

The second line baffles me????
Thanks for the help folks

[Squashman]

Code: Select all

copy "%~1" "F:\PUBLIC\shared\Lathe\ScrewMills\temp\"

[Squashman]

From the CALL Help file. I know. Whacky place to document it.

Code: Select all

In addition, expansion of batch script argument references (%0, %1,
etc.) have been changed as follows:


    %* in a batch script refers to all the arguments (e.g. %1 %2 %3
        %4 %5 ...)

    Substitution of batch parameters (%n) has been enhanced.  You can
    now use the following optional syntax:

        %~1         - expands %1 removing any surrounding quotes (")
        %~f1        - expands %1 to a fully qualified path name
        %~d1        - expands %1 to a drive letter only
        %~p1        - expands %1 to a path only
        %~n1        - expands %1 to a file name only
        %~x1        - expands %1 to a file extension only
        %~s1        - expanded path contains short names only
        %~a1        - expands %1 to file attributes
        %~t1        - expands %1 to date/time of file
        %~z1        - expands %1 to size of file
        %~$PATH:1   - searches the directories listed in the PATH
                       environment variable and expands %1 to the fully
                       qualified name of the first one found.  If the
                       environment variable name is not defined or the
                       file is not found by the search, then this
                       modifier expands to the empty string

    The modifiers can be combined to get compound results:

        %~dp1       - expands %1 to a drive letter and path only
        %~nx1       - expands %1 to a file name and extension only
        %~dp$PATH:1 - searches the directories listed in the PATH
                       environment variable for %1 and expands to the
                       drive letter and path of the first one found.
        %~ftza1     - expands %1 to a DIR like output line

    In the above examples %1 and PATH can be replaced by other
    valid values.  The %~ syntax is terminated by a valid argument
    number.  The %~ modifiers may not be used with %*