Multi-line indentation

[treintje]

I'm looking for an explanation why I cannot put the carrot behind the OR operator:

Code: Select all

md "dir" ||^
  echo Failed to make dir

But putting the carrot in front of OR seems to be fine.

Code: Select all

md "dir" ^
  || echo Failed to make dir

And is there a way to put the opening parenthesis of an if-block onto the next line?

Code: Select all

if "%x%" == "%y%" ^
(
  echo Match found
)

[Squashman]

A double pipe is not an OR. It is conditional execution. If the previous command fails then execute the next command. A double ampersand executes the next command if the previous command was successful.

[treintje]

It seems that I used the wrong terminology for the double pipe operator. I still don't understand the ruling of the ^ anchor operator, an explanation why certain codes can be split up to the next line and others don't, would be very much appreciated.

[foxidrive]

I still don't understand the ruling of the ^ anchor operator

It would help to know what you are actually doing with your code as the answers can be very different, and we end up wasting our time.

The caret is a line-continuation character, and also an escape character.

[penpen]

The escape character circumflex accent ('^') is working finde even after conditional execution.
But you are underestimating the consequences:
The next character is treated as no special character (by the scanner of the command line interpreter).

In your first example the next character to the scanner is the space character in the next line.
This space is now handled as a normal character (and not as a separator character).
After this character a second space character is found, which is a separator.
So the space is the first token of a single instruction which is defined as the command-
This command (" ") is unknown.

So you have to remove all characters in front of echo to make this example work:

Code: Select all

md "dir" ||^
echo Failed to make dir 

(The 'e' is treated as a normal character, which is its default meaning.)

For the same reason the '(' is treated as a normal charcter.
But you cannot add seperator characters in front of the '(' to let the opening parenthesis be a special character for the above reason.
So you have to redirect stderr to nul (you don't want to see the error message 'command " " unknown', or similar) and add an ampersand to execute multiple commands:

Code: Select all

if "%x%" == "%y%" ^
  2>nul & (
  echo Match found.
) else (
  echo Match not found.
)

Sidenote:
A "scanner"/"lexer" reads the source code lines and transforms each line into a sequence of (so called) tokens (smallest meaningful units) and is a part of an interpreter.


penpen

[treintje]

Thank you for your explanation, penpen. It is really helpful to me.

The next character is treated as no special character (by the scanner of the command line interpreter).

This is particularly useful to know.

To get a better understanding of how the "scanner/lexer" works, I did some tests and managed to get some sort of GNU style indenting to work with the if command.

Code: Select all

if "%x%"^ == "%y%"^
  (
    echo Match found
  )

I am aware that there are a lot of drawbacks by doing this and it only seems to work when at least two leading spaces are used in front of the open parenthesis '('. It seems as if the if command is actually comparing '"%x%"^ ' with '"%y%"^ ' (note the trailing spaces). Is that correct?

[penpen]

Yes, that is correct.

If you are interested in details, you should also note, that typically there are multiple scanners involved in interpreting a batch file.
(In common we don't differ between all these scanners and treat it as one scanner only.)

The command line interpreter (cli) itself divides each instruction into one 'command', one 'argument' and one redirection string:
The redirection is applied, the command is executed with the given argument string, and the redirections are 'restored'.
(If echo is on, the command that will be executed is first displayed in a normalized form (redirections are always last).)

But the cli also uses different parsers; for example when accessing the single command line parameters versus the command line parameter string (for example unescaped ',' characters outside doublequotes are stripped of %1 while they are present in %*).

Each command that is executed may also have its own parser; the following "test.bat" could be used to show one difference between call/batch and js/csrcipt:

Code: Select all

@if (true == false) @end /*
@echo off
setlocal enableDelayedExpansion enableExtensions

cscript //E:JScript //Nologo "%~f0" %*
call :3arguments %*

endlocal
goto :eof

:3arguments
   echo %%1 = %1
   echo %%2 = %2
   echo %%3 = %3

   goto :eof
*/
for (var i = 0; i < WScript.Arguments.length; ++i) {
   WScript.echo("WScript.Arguments.Item(" + i + ") = " + WScript.Arguments.Item(i));
}

This shows one difference:

Code: Select all

Z:\>test.bat ^^^^"1" "2^" "3"
WScript.Arguments.Item(0) = ^1
WScript.Arguments.Item(1) = 2^
WScript.Arguments.Item(2) = 3
%1 = "1"
%2 = "2^^"
%3 = "3"

penpen

[Squashman]

Here is some good documentation that Jeb put together on SO.
http://stackoverflow.com/a/4095133/1417694

[foxidrive]

To get a better understanding of how the "scanner/lexer" works, I did some tests and managed to get some sort of GNU style indenting to work with the if command.

Code: Select all

if "%x%"^ == "%y%"^
  (
    echo Match found
  )

I am aware that there are a lot of drawbacks by doing this and it only seems to work when at least two leading spaces are used in front of the open parenthesis '('.

Excuse me if I seem to be a little ranty these days but this bloke asked a question and had this example as the third item. It seems as though this is what he was trying to achieve in the first place.

penpen you've gone to a lot of effort to decribe highly technical items to this person and you do a good job of it, as you normally do.


What cheeses me off is people asking a question with misleading ways of asking that question.


As an aside:
For the life of me I can't see any good reason to use non-standard ways of laying out code in a batch script, unless you're trying to confuse some poor bunny down the track who has to decipher that code. Maybe the next employee that follows in that role.

I'll pop a couple of anti-ranty pills and see how they kick in. Maybe half a bottle of Johnny Walker instead.