Different behaviour of a command on XP and WIN10

[miskox]

Hello all!

Code: Select all

@echo off
set cmmnt= &rem ONE SPACE
<nul set /p "=%cmmnt%" >temporary.cmmnt
for %%q in (temporary.cmmnt) do (set /a strlen=%%~zq)
echo strlen=%strlen%_

Executing this on XP gives result 1, executing this on WIN10 gives rezult 0. Any ideas why?

Changing the code to:

Code: Select all

@echo off
set cmmnt= &rem ONE SPACE
echo(%cmmnt%>temporary.cmmnt
for %%q in (temporary.cmmnt) do (set /a strlen=%%~zq)
set /a strlen-=2
echo strlen=%strlen%_

Gives correct result 1.

Saso

[jeb]

Hi miskox,

the difference is in the set /p behaviour.
This is changed from XP to Vista.
From Vista leading white space characters are removed from the output.

That's the cause, W10 removes the space and writes an empty file.

[dbenham]

I tried to document the output behavior of SET /P under XP vs later versions at viewtopic.php?f=3&t=4209.

Presumably Win 10 behaves the same as Vista and Win 7


Dave Benham

[miskox]

What can I do?

I see that commands:

Code: Select all

echo(%cmmnt%>temporary.cmmnt

and

Code: Select all

>temporary.cmmnt (echo(%cmmnt%)

are causing me problems if cmmnt contains ( or ).

I will see if this viewtopic.php?f=3&t=4213 helps me.

Thanks.
Saso

[dbenham]

The standard answer whenever trying to work with "problem" characters - Use delayed expansion.
Works in all situations except when expanding FOR loop variable that may contain !

Code: Select all

setlocal enableDelayedExpansion
>temporary.cmmnt echo(!cmmnt!
endlocal

Dave Benham

[miskox]

The standard answer whenever trying to work with "problem" characters - Use delayed expansion.
Works in all situations except when expanding FOR loop variable that may contain !

Code: Select all

setlocal enableDelayedExpansion
>temporary.cmmnt echo(!cmmnt!
endlocal

Dave Benham

Thank you.

Problem solved.

Saso