Problem with Data from Parentheses to be Piped to Findstr

[Meerkat]

I have a sample code:

Code: Select all

@echo off
setlocal enabledelayedexpansion

set l=100
for /l %%. in (1,1,%l%) do (
    set /a "C_%%.=%%.*%%."
)

::First section: This works
(
for /l %%. in (1,1,%l%) do echo %%.
)|findstr /BC:"4"
pause

::Second section: This prints stuff
(
for /l %%. in (1,1,%l%) do echo !c_%%.!
)
pause

::Third section: This does NOT work
(
for /l %%. in (1,1,%l%) do echo !c_%%.!
)|findstr /BC:"4"
pause

From what I observed, the third section does not work because delayed variables are ECHOed and piped thru Findstr, but I don't see a connection. How can I fix that?

Meerkat

[aGerman]

You could run it in a separate cmd process. Give that a go:

Code: Select all

(
cmd /von /q /c "for /l %%. in (1,1,%l%) do echo !c_%%.!"
)|findstr /BC:"4"

Steffen

[dbenham]

Yes - aGerman has the solution.

The reason your code fails is because each side of the pipe is run in a new cmd session where delayed expansion defaults to off.

See http://stackoverflow.com/q/8192318/1012053 for more information.


Dave Benham

[Meerkat]

Code: Select all

(
cmd /von /q /c "for /l %%. in (1,1,%l%) do echo !c_%%.!"
)|findstr /BC:"4"

Steffen

Thanks! Just a followup question. Just in case, how can I put it in the IN clause of FOR loop?

Meerkat

[jeb]

One way is to use a cmd variable first.

Code: Select all

set "cmd=(cmd /von /q /c "for /l %%. in (1,1,%l%) do echo !c_%%.!")^| findstr /BC:"4""
setlocal EnableDelayedExpansion
for /F "delims=" %%X in ('!cmd!') do echo ## %%X

But I suppose, that it's much too complicated to use it this way.

This should work, too

Code: Select all

for /l %%. in (1,1,%l%) do (
   set "content=!c_%%.!"
   if "!content:~0,1!"=="4" echo ** !content!

[pieh-ejdsch]

command IF is parsing two times.
It also run without auxiliary variables:

Code: Select all

for /l %%. in (1,1,%l%) do if :!c_%%.:~0^,1!==:4 echo !c_%%.!

Phil

[Meerkat]

Thanks for the answers!

Meerkat