remove non significative 0 in number

[darioit]

Hello everybody,

it's possible to do this in another way or with awk

the result must be a number without first non significative number0

Example row = "qwertyabc 000123"
I want extract with position start %rec2% and end %rec3% get the number 123 without initial 0

this is my code

Code: Select all

@echo off
set line1="qwertyabc 000123"
set Rec2=11
set Rec3=6

CALL SET rec_tot=1%%line1:~%Rec2%,%Rec3%%%
SET /A rec_tot=2*rec_tot-2%rec_tot:~1%
echo %rec_tot%

pause

Regards
Dario

[aGerman]

What about a FOR loop

Code: Select all

@echo off &setlocal enabledelayedexpansion
set line1="qwertyabc 000123"
set Rec2=11
set Rec3=6

for /f "delims=0 tokens=*" %%a in ("!line1:~%Rec2%,%Rec3%!") do echo %%a

pause

[ghostmachine4]

when you add you 0 to the field of numbers, awk "converts" it to integer "automagically"

Code: Select all

C:\test>echo qwertyabc 000123| gawk "{for(i=1;i<=NF;i++) if($i ~ /^[0-9]*$/) $i=$i+0}{print}"
qwertyabc 123

the above says, go through every field, check for digits, then add 0 to that field.
If you want to continue using this useful tool please read up on it here.. With adequate knowledge, it can replace cmd.exe as your lightweight programming tool.

[ghostmachine4]

What about a FOR loop

Code: Select all

@echo off &setlocal enabledelayedexpansion
set line1="qwertyabc 000123"
set Rec2=11
set Rec3=6

for /f "delims=0 tokens=*" %%a in ("!line1:~%Rec2%,%Rec3%!") do echo %%a

pause

this is not a generic solution. What if the digits are else where and not at the specified positions?

[orange_batch]

Ouch guys, I know you can do better than that!

Code: Select all

@echo off&setlocal enabledelayedexpansion
set "line1=qwertyabc 000123"

for /f "tokens=1*" %%x in ("!line1!") do (
for /f "delims=0 tokens=*" %%z in ("%%y") do set numbers=%%z
)

echo:%numbers%

I changed it so line1 doesn't surround qwertyabc 000123 with quotes.

The first for splits the value of line1 where the space is.

The second for processes the second token of line1 (the numbers), removes any leading 0s and sets the value to numbers.

This can be useful when doing DOS math with numbers that have leading 0s, because DOS interprets any numbers with leading 0s as octal instead of decimal.

The for block can be easily shortened to a single line if you want...

Code: Select all

for /f "tokens=1*" %%x in ("!line1!") do for /f "delims=0 tokens=*" %%z in ("%%y") do set numbers=%%z

[ghostmachine4]

@orange, interesting..but there are flaws.

Code: Select all

C:\test>more test.bat
@echo off&setlocal enabledelayedexpansion
set "line1=qwertyabc 123xx 000123"

for /f "tokens=1*" %%x in ("!line1!") do (
for /f "delims=0 tokens=*" %%z in ("%%y") do set numbers=%%z
)

echo:%numbers%

C:\test>test.bat
123xx 000123

123xx is not a string of digits so it shouldn't be output... and 000123 is not converted.

[amel27]

extract with position start %rec2% and end %rec3% get the number 123 without initial 0

%rec3% is not required

Code: Select all

@echo off
SetLocal EnableDelayedExpansion

set "line=qwer yabc 000123 xxx"
set "skip=10"

for /f "tokens=* delims=0" %%i in ("!line:~%skip%!") do for /f %%a in ("%%i") do echo %%a

Code: Select all

@set "line=qwer yabc 000123 xxx"
@set "skip=10"
@set line|awk --re-interval "{f=gensub(/^[^=]*=.{%skip%}0*([0-9]+).*$/,\"\\1\",1);print f}"

[ghostmachine4]

Code: Select all

@set "line=qwer yabc 000123 xxx"
@set "skip=10"
@set line|awk --re-interval "{f=gensub(/^[^=]*=.{%skip%}0*([0-9]+).*$/,\"\\1\",1);print f}"

there is no requirement to search for the "=" sign. There may not be equal signs in the string itself. OP just wanted any 000{digits} to be converted to remove leading 0's. And your awk reg expression capture only substitute 1 set of 000{digits}. you could use "g" instead to replace all.

Code: Select all

C:\test>echo qwer yabc 000123 0000123 0123xx |gawk --re-interval "{f=gensub(/\y0+([0-9]+)\y/,\"\\1\",\"g\");print f}"
qwer yabc 123 123 0123xx

[aGerman]

What about a FOR loop

Code: Select all

@echo off &setlocal enabledelayedexpansion
set line1="qwertyabc 000123"
set Rec2=11
set Rec3=6

for /f "delims=0 tokens=*" %%a in ("!line1:~%Rec2%,%Rec3%!") do echo %%a

pause

this is not a generic solution. What if the digits are else where and not at the specified positions?

Required was:

I want extract with position start %rec2% and end %rec3% get the number 123 without initial 0

Regards
aGerman

[orange_batch]

@orange, interesting..but there are flaws.

Code: Select all

C:\test>more test.bat
@echo off&setlocal enabledelayedexpansion
set "line1=qwertyabc 123xx 000123"

for /f "tokens=1*" %%x in ("!line1!") do (
for /f "delims=0 tokens=*" %%z in ("%%y") do set numbers=%%z
)

echo:%numbers%

C:\test>test.bat
123xx 000123

123xx is not a string of digits so it shouldn't be output... and 000123 is not converted.

I wrote it to handle a string in the format provided by the OP, so obviously more spaces would cause a failure. It doesn't need * as the second for's token either, if it's just a string of numbers with no spaces, but it shouldn't matter.

To be precise, it removes leading zeros from the second value of a space/tab delimited string and sets everything that follows.

[amel27]

there is no requirement to search for the "=" sign.

type:

Code: Select all

@set "line=qwer yabc 000123 xxx"
@set line

result:

line=qwer yabc 000123 xxx

your awk reg expression capture only substitute 1 set of 000{digits}. you could use "g" instead to replace all

regular expression like "^...$" has only 1 entry per line...

[ghostmachine4]

@aGerman, amel27, i don't know about you, but i don't assume that OP wants to really hard code that one piece of string in his batch. I would assume that lines come from somewhere else, like a file or some standard output where positions aren't fixed and that there are other line formats with one or more 0*{digits}.

[ghostmachine4]

expression like "^...$" has only 1 entry per line...

that i know. your code may work if that's the only type of line OP has and has ONLY one "000123".

[amel27]

your code may work if that's the only type of line OP has and has ONLY one "000123".

yes!.. every line has ONLY one fixed position %rec2%

P.S. it is possible too - some tools formatting output fields by position, not by delimiters