Delete directory and files with subdirectorys with ftp command line

[Squashman]

I know with the builtin Windows FTP.exe program you can actually pipe your commands to the program. Maybe you can do that with ncpftp as well.

Code: Select all

(echo open -u FtpAddress
echo FtpUsername
echo FtpPassword
echo mkdir AAA
echo cd AAA
echo mkdir 1A
echo mkdir 2B
echo mkdir 3C
echo cd ..
echo rm -r )|ncftp

Worth a try.

[r2du-soft]

I know with the builtin Windows FTP.exe program you can actually pipe your commands to the program. Maybe you can do that with ncpftp as well.

Code: Select all

(echo open -u FtpAddress
echo FtpUsername
echo FtpPassword
echo mkdir AAA
echo cd AAA
echo mkdir 1A
echo mkdir 2B
echo mkdir 3C
echo cd ..
echo rm -r )|ncftp

Worth a try.

i tryed

Code: Select all

(echo open -u 138.201.29.24
echo test@update.iranisc.ir
echo testuL4O92t2Go~3
echo mkdir BBB
echo mkdir AAA
echo cd AAA
echo mkdir 1A
echo mkdir 2B
echo mkdir 3C
echo cd ..
echo rm -r )|ncftp

pause

FTP INFO:
Ftp Address: ftp://138.201.29.24
Ftp Username: test@update.iranisc.ir
Ftp Password: testuL4O92t2Go~3

but not work and i see this:

[img]
http://uupload.ir/files/vyi_ncftp.jpg
[/img]

[Compo]

The NcFTP program supports command line arguments to log you in to the remote server but that's all; any other commands need to be entered interactively.

They also additionally created NcFTPGet, NcFTPPut and NcFTPLs to allow for an additional degree of non interactivity, but those won't cover your intended tasks

[r2du-soft]

Thanks Compo
Nevertheless How can I do this?

[aGerman]

Tried a combination of NcFTPLs and FTP

Code: Select all

@echo off &setlocal

set "uname=test@abc.def.ir"
set "passw=test12345"
set "hostn=ftp://abc.def.ir"
set "rootdir=Root"
set "lsfile=dirlist.txt"
set "ftpscript=test.ftp"

>"%lsfile%" (
  for /f "tokens=8 delims=;" %%i in (
    'ncftpls -u "%uname%" -p "%passw%" -R -m "%hostn%" ^| findstr /xrc:"type=dir;..*;[ ]*%rootdir%/[^;][^;]*"'
  ) do for /f "tokens=*" %%j in ("%%i") do echo %%j
)

>"%ftpscript%" (
  for /f "delims=" %%i in ("%hostn%") do echo open %%~nxi
  echo %uname%
  echo %passw%
  for /f "delims=" %%i in ('sort /r "%lsfile%"') do (
    echo cd %%i
    echo mdel *
    echo cd ..
    for %%j in ("%%i") do echo rmdir %%~nxi
    echo cd /
  )
  echo disconnect
  echo bye
)
ftp.exe -i -s:"%ftpscript%"

This seems to be working. At least I managed to successfully empty your Root folder even that I created a deeper structure with files beforehand.

Steffen