problem with choice command

[gunitinug]

Code: Select all

@echo off
CHOICE /C YNO /T 10 /D Y /M "Are you feeling awesome?"
IF ERRORLEVEL 1 goto yes
IF ERRORLEVEL 2 goto no
IF ERRORLEVEL 3 goto other

:yes
echo you are awesome!
goto end

:no
echo bad luck.
goto end

:other
echo unique ;)
goto end

:end

For every choice returns "you are awesome!". I'm expecting different responses with each choice. THX

[Squashman]

From the help file for the IF command.

Code: Select all

ERRORLEVEL number Specifies a true condition if the last program run
                    returned an exit code equal to or greater than the number
                    specified.

And from the help for the CHOICE command.

Code: Select all

When you use ERRORLEVEL parameters in a batch program, list
   them in decreasing order.

In other words. Reverse your IF statements.

Your other option is to use the %errorlevel% variable.

Code: Select all

IF "%errorlevel%"=="1" goto yes

[Aacini]

... or completely eliminate all those IF commands!

Code: Select all

@echo off
CHOICE /C YNO /T 10 /D Y /M "Are you feeling awesome?"
goto option-%errorlevel%

:option-1 yes
echo you are awesome!
goto end

:option-2 no
echo bad luck.
goto end

:option-3 other
echo unique ;)
goto end

:end

Antonio

[penpen]

You may want to cover the possibility of CTRL+C as a choice-input:

Code: Select all

::...

:option-0 CTRL+C
echo aborted.
goto end

:option-1 yes
: ...

penpen