Coding issues

[jackjack]

If anyone can help me this would be great.

so I am needing to do a simple check after a user has inputted information,

I only want the check to be approved if they have only entered 6 colours if not it fails.

I was trying to do it in 6 different IF statements but its to clunky

Code: Select all

set /p "myVar=---> " 
echo %myVar%|findstr /ix "red:Red:blue:Blue">nul && ( 
 echo %myVar% matched 
 ) || ( 
 echo %myVar% not matched 
 )

above is what I tried to get working however I don't think it is picking up all the colors and I get an error message saying 'the system can not fine the system file blue'

if anyone has got any ideas on how this can be fixed that would be great.

many thanks

[Squashman]

You have not really specified how the user is entering those 6 colors. You are also only checking two colors.

You also have not provided any feedback on all the help that has been provided to you on StackOverFlow.
https://stackoverflow.com/questions/500 ... user-input

[jackjack]

So it will ask the user to enter a color, and it can be 6 colors but I need to make sure that it is only them 6 colors,

so they will be set in a variable already defined

[jackjack]

If any one is able to help me

I am using this code

Code: Select all

if NOT "%color%"=="blue" (
 GOTO :colorError
 ) else (
 echo working
 )

but I want to add green and red into the statement, how can I do this please

many thanks

[Squashman]

Give this a try.

Code: Select all

@echo off
setlocal EnableDelayedExpansion
set "colors=redorangeyellowgreenblueindigo"
set /p "ucolor=Enter a color--->"

IF "!colors:%ucolor%=!"=="%colors%" (
	echo %ucolor% is an invalid color
) else (
	echo Your color is: %ucolor%
)
pause

[Aacini]

Give this a try.

Code: Select all

@echo off
setlocal EnableDelayedExpansion
set "colors=redorangeyellowgreenblueindigo"
set /p "ucolor=Enter a color--->"

IF "!colors:%ucolor%=!"=="%colors%" (
	echo %ucolor% is an invalid color
) else (
	echo Your color is: %ucolor%
)
pause

Your method is good. However, each value should be separated by a delimiter character; otherwise it would be too many wrong values that would be accepted as valid, like "do", "edo", "edor", and a long et cetera...

Code: Select all

@echo off
setlocal EnableDelayedExpansion
set "colors=/red/orange/yellow/green/blue/indigo/"
set /p "ucolor=Enter a color--->"

IF "!colors:/%ucolor%/=!" == "%colors%" (
	echo %ucolor% is an invalid color
) else (
	echo Your color is: %ucolor%
)
pause

Antonio

[Squashman]

I agree Antonio. So lets take it a step further.

Code: Select all

@echo off
setlocal EnableDelayedExpansion
set "colors=/red/orange/yellow/green/blue/indigo/"
set /p "ucolor=Enter a color--->"
set "empty="
set "delims=abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ"
FOR /F "delims=%delims%" %%G IN ("%ucolor%") DO SET "empty=%%G"

IF DEFINED emtpy (
	echo invalid entry
	pause
	GOTO :EOF
)

IF "!colors:/%ucolor%/=!" == "%colors%" (
	echo %ucolor% is an invalid color
) else (
	echo Your color is: %ucolor%
)
pause

This basically only protects against them entering: red/orange as input.

[Aacini]

I agree Antonio. So lets take it a step further.

Code: Select all

@echo off
setlocal EnableDelayedExpansion
set "colors=/red/orange/yellow/green/blue/indigo/"
set /p "ucolor=Enter a color--->"
set "empty="
set "delims=abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ"
FOR /F "delims=%delims%" %%G IN ("%ucolor%") DO SET "empty=%%G"

IF DEFINED emtpy (
	echo invalid entry
	pause
	GOTO :EOF
)

IF "!colors:/%ucolor%/=!" == "%colors%" (
	echo %ucolor% is an invalid color
) else (
	echo Your color is: %ucolor%
)
pause

This basically only protects against them entering: red/orange as input.

I think it is much simpler to just change the IF command in this way instead:

Code: Select all

IF "!colors:/%ucolor:/=%/=!" == "%colors%" (

Antonio