Unable to produce truthful info about deletion or lack of thereof [SOLVED]

[DOSadnie]

I have this code

Code: Select all

set "THIS-WILL-BE-DELETED=C:\Users\YOUR-USER-NAME\AppData\Roaming\ASCOMP Software\BackUp Maker"

del /q "%THIS-WILL-BE-DELETED%\*.*"

dir "%THIS-WILL-BE-DELETED%" 1>NUL 2>&1

if errorlevel 1 (
    echo Files were deleted at
    echo.
    echo C:\Users\YOUR-USER-NAME\AppData\Roaming\ASCOMP Software\BackUp Maker

) else (
    echo There was nothing to delete at
    echo.
    echo C:\Users\YOUR-USER-NAME\AppData\Roaming\ASCOMP Software\BackUp Maker
)

pause

which is suppose to inform me if files were or were not deleted - but it always uses the text from >>else<< i.e. it lies about not deleting

How can this be fixed?

[ShadowThief]

Delete the folder instead of emptying it, then use if exist to see if the folder is there. dir will always return something when it's inside of a folder that exists, so it's always going to return an %errorlevel% of zero.

[DOSadnie]

I cannot delete it as it has sub-folders that I need to keep

[Batcher]

dir /b /a-d "%THIS-WILL-BE-DELETED%" 1>NUL 2>&1

[DOSadnie]

This did not help: I still get Files were deleted at reported even if nothing has been deleted

[ShadowThief]

Why do you even want the "There was nothing to delete" message? Whether there was or was not anything in the folders before the script was run, there is currently nothing in the folders after the fact. The message is useless.

[DOSadnie]

Such message is not useless if it is a part of a large script that deals with erasing of various clutter from many locations- thus reading some parts of an aftermath raport is sometimes vital to me

[Batcher]

Code: Select all

set "THIS-WILL-BE-DELETED=C:\Users\YOUR-USER-NAME\AppData\Roaming\ASCOMP Software\BackUp Maker"
dir /b /a-d "%THIS-WILL-BE-DELETED%" 1>NUL 2>&1
if not errorlevel 1 (
    del /q "%THIS-WILL-BE-DELETED%\*.*"
    echo Files were deleted at
) else (
    echo There was nothing to delete at
)

[DOSadnie]

This works, thank you

I have adjusted it slightly to this:

Code: Select all

@echo off

set "FILES-IN-THIS-FOLDER-WILL-BE-DELETED=C:\Users\YOUR-USER-NAME\AppData\Roaming\ASCOMP Software\BackUp Maker"

dir /b /a-d "%FILES-IN-THIS-FOLDER-WILL-BE-DELETED%" 1>nul 2>&1

if not errorlevel 1 (
    echo. Deleted files at
    echo.
    echo  %FILES-IN-THIS-FOLDER-WILL-BE-DELETED%
    echo.
    echo.

    for %%F in ("%FILES-IN-THIS-FOLDER-WILL-BE-DELETED%\*.*") do (
        echo.
        echo                                                                      %%~nxF
        del /q "%%F"
    )
) else (
    echo. There was nothing to be deleted at
    echo.
    echo  %FILES-IN-THIS-FOLDER-WILL-BE-DELETED%
)

pause