FOR /F loop text files: why blank lines are skipped?

[tinfanide]

Code: Select all

@ECHO OFF
SETLOCAL ENABLEDELAYEDEXPANSION

< 6.txt (
   FOR /F "delims=" %%A IN (5.txt) DO (
      SET str=
      SET /P str=

      
      ECHO %%A - !str!
   )
)

PAUSE

5.txt

a

b
c

6.txt

a

d
e

a - a
b -
c - d
Press any key to continue . . .

[aGerman]

Because that's the way FOR /F works
Try:

Code: Select all

...
FOR /F "tokens=1* delims=:" %%A IN ('FINDSTR /N "^" "5.txt"') DO (
...
      ECHO %%B - !str!
...

Regards
aGerman

EDIT:
To avoid faults with leading colons:

Code: Select all

...
FOR /F "delims=" %%A IN ('FINDSTR /N "^" "5.txt"') DO (
...
      ECHO %%A - !str:*:=!
...

[miskox]

Code: Select all

help for

says:

Code: Select all

Blank lines are skipped.

Saso

[tinfanide]

Because that's the way FOR /F works
Try:

Code: Select all

...
FOR /F "tokens=1* delims=:" %%A IN ('FINDSTR /N "^" "5.txt"') DO (
...
      ECHO %%B - !str!
...

Regards
aGerman

EDIT:
To avoid faults with leading colons:

Code: Select all

...
FOR /F "delims=" %%A IN ('FINDSTR /N "^" "5.txt"') DO (
...
      ECHO %%A - !str:*:=!
...

Code: Select all

< 6.txt (
   FOR /F "tokens=1* delims=:" %%A IN ('FINDSTR /N "^" "5.txt"') DO (
        SET str=
        SET /P str=
        ECHO %%B - !str!
   )
)

Code: Select all

< 6.txt (
   FOR /F "delims=" %%A IN ('FINDSTR /N "^" "5.txt"') DO (
        SET str=
        SET /P str=
        ECHO %%A - !str:*:=!
   )
)

The first version works better than the second one because
the second one produces

first:

a - a
-
b - d
c - e

second

1:a - a
2: - *:=
3:b - d
4:c - e

It seems that

Code: Select all

!str:*:=!

does not substitute the string "*:" for "".

[aGerman]

My fault.

Code: Select all

@ECHO OFF
< 6.txt (
FOR /F "delims=" %%A IN ('FINDSTR /N "^" "5.txt"') DO (
      SET str=
      SET /P str=
      SET "str2=%%A"
      SETLOCAL ENABLEDELAYEDEXPANSION
        ECHO !str2:*:=! - !str!
      ENDLOCAL
   )
)
PAUSE

Regards
aGerman

[tinfanide]

Yes, it works.